The Hooking into Google Analytics post details how to connect to the Data Export API of Google Analytics (GA) and get a simple visitors count in return. Here we will expand greatly on that and create a cfc that will process just about any result from the API.

This code requires at least ColdFusion 8.0.1. Check your version before installing.

An auth token is needed for requests to the API and two ways to do that are the AuthSub and ClentLogin methods. The method used is up to the developer as once the auth token is retrieved and set into session, data calls to the API can be repeatedly made.

<cffunction name="googleLogin" access="public" hint="GA account authorization">
        <cfargument name="email" type="string" required="yes" default="">
        <cfargument name="password" type="string"required="yes" default="">
        <cfargument name="gaLoginUrl" type="string" required="no" default="https://www.google.com/accounts/ClientLogin">

        <cfset var loginAuth = "" />

        <cfhttp url="#arguments.gaLoginUrl#" method="post">
            <cfhttpparam name="accountType" type="url" value="GOOGLE">
            <cfhttpparam name="Email" type="url" value="#arguments.email#">
            <cfhttpparam name="Passwd" type="url" value="#arguments.password#">
            <cfhttpparam name="service" type="url" value="analytics">
            <cfhttpparam name="source" type="url" value="my-analytics">
        </cfhttp>

        <cfif NOT FindNoCase("Auth=",cfhttp.filecontent)>
            <cfset loginAuth = "Authorization Failed" />
        <cfelse>
            <cfset loginAuth = Mid(cfhttp.filecontent, FindNoCase("Auth=",cfhttp.filecontent) + (Len("Auth=")), Len(cfhttp.filecontent)) />
        </cfif>

         <cflock scope="session" type="exclusive" timeout="5">
                <cfset session.ga_loginAuth = loginAuth />
         </cflock>

    </cffunction>

To retrieve the profile or data feed, a call is made to the API via a function.

   <cffunction name="callApi" access="public" returntype="array" hint="GA data as array of structures">
        <cfargument name="gaUrl" type="string" required="yes">
        <cfargument name="authToken" type="string" required="no" default="#session.ga_loginAuth#" />

        <cfset var authTokenHeader = 'GoogleLogin auth=' & arguments.authToken />

        <cfset var responseOutput = "" />

        <cfhttp url="#arguments.gaUrl#" method="get">
            <cfhttpparam name="Authorization" type="header" value="#authTokenHeader#">
        </cfhttp>

        <cfset responseOutput = cfhttp.filecontent />
        <!---remove dxp: prefix from nodes that have it and strip xmlns from feed element--->
         <cfset responseOutput = responseOutput.ReplaceAll("(</?)(\w+:)","$1") />
         <cfset responseOutput = REReplaceNoCase(responseOutput,"<feed[^>]*>","<feed>") />
         <!---entry nodes hold the data--->
         <cfset entryNodes = XmlSearch(responseOutput, '//entry/') />

         <cfreturn entryNodes />
    </cffunction>

Next, a list of the profiles (websites) that the user has access to are retrieved by requesting an account feed. If the user has only one profile associated with their credentials, the data is displayed immediately. If they have more than one, they are presented with a select box to select the profile they want data from.

<cfinvoke component="ga" method="parseProfiles" returnvariable="profilesArray"></cfinvoke>

 <cffunction name="parseProfiles" access="public" returntype="array" hint="GA profiles as array of structures">

	<cfset var profileArray = ArrayNew(1) />
        <cfset var entryStruct = StructNew() />

        <cfset entryNodes = callApi("https://www.google.com/analytics/feeds/accounts/default") />

        <cfloop array="#entryNodes#" index="entry">
            <cfset entryStruct = StructNew() />

            <cfset entryStruct.title = entry.title.XmlText />
            <cfset entryStruct.tableId = entry.tableId.XmlText />

            <cfset arrayAppend(profileArray,duplicate(entryStruct)) />
        </cfloop>

        <cfreturn profileArray />
    </cffunction>

A default date range of one year is set initially. A dialog box that allows the user to change the date range is presented as an option. The date range is limited to a max date of yesterday because GA does not have full data for the current day. This causes the averages that are calculated on the return data to be skewed.

A data feed request url is sent to GA along with the auth token a via cfhttp tag.

<cfset reqUrl = "https://www.google.com/analytics/feeds/data?ids=" & session.tableId & "&metrics=ga:newVisits,ga:pageviews,ga:visits,ga:visitors,ga:timeOnSite&start-date=" & session.startdate & "&end-date=" & session.enddate />

The XML response is then parsed out and returned as an array of structures.

<cffunction name="parseData" access="public" hint="GA data as array of structures set in session">
        <cfargument name="gaUrl" type="string" required="yes" />
        <cfargument name="arrayName" type="string"required="yes" />

        <cfset var dataArray = ArrayNew(1) />
        <cfset var entryStruct = StructNew() />

         <cfset entryNodes = callApi(arguments.gaUrl) />

        <!---CF8 loop through the entries and put each data point in structure--->
        <cfloop from="1" to="#ArrayLen(entryNodes)#" index="num">
		<!---rest of the stats data from GA, first check if dimension exists--->
		<cfif StructKeyExists(entryNodes[num],"dimension")>
		<cfloop from="1" to="#ArrayLen(entryNodes[num].dimension)#" index="i">
		<!---start after ga: to remove it--->
		<cfset "entryStruct.#Mid(entryNodes[num].dimension[i].XmlAttributes["name"],4,
Len(entryNodes[num].dimension[i].XmlAttributes["name"]))#" = entryNodes[num].dimension[i].XmlAttributes["value"] />
		</cfloop>
		</cfif>

		<cfloop from="1" to="#ArrayLen(entryNodes[num].metric)#" index="i">
			<cfset "entryStruct.#Mid(entryNodes[num].metric[i].XmlAttributes["name"],4,
Len(entryNodes[num].metric[i].XmlAttributes["name"]))#" = entryNodes[num].metric[i].XmlAttributes["value"] />
		</cfloop>

		<cfset arrayAppend(dataArray,duplicate(entryStruct)) />

	</cfloop>

         <!---CF9 can use this simplier loop. If you have CF9, uncomment and delete loop above
            <cfloop array="#entryNodes#" index="entry">
		<cfif StructKeyExists(entry,"dimension")>
                	<cfloop array="#entry.dimension#" index="dimension">
                 	<cfset "entryStruct.#Mid(dimension.XmlAttributes["name"],4,
Len(dimension.XmlAttributes["name"]))#" = dimension.XmlAttributes["value"] />
                 	</cfloop>
                 </cfif>

                 <cfloop array="#entry.metric#" index="metric">
                 	<cfset "entryStruct.#Mid(metric.XmlAttributes["name"],4,
Len(metric.XmlAttributes["name"]))#" = metric.XmlAttributes["value"] />
                  </cfloop>

                <cfset arrayAppend(dataArray,duplicate(entryStruct)) />
           </cfloop>--->

        	<cflock scope="session" type="exclusive" timeout="5">
        		<cfset "session.#arrayName#" = dataArray />
        	</cflock>

    </cffunction>

Once the data is in a form you can manipulate, graphs, tables, and charts of all kinds can be made.

ClientLogin, AuthSub, and Secure AuthSub authentication examples are included in the demo. ClientLogin recommended only for client apps. Google notice on using ClientLogin:

“Important: Do not use ClientLogin if you are writing an application that runs on
your computer to make requests on behalf of 3rd party end users. Instead, use either
AuthSub or OAuth, which protects end users’ private data. Because ClientLogin stores
the user login data, it should only be used in cases where that data is under the
direct control of the user (e.g. their personal computer).”

Recommended Reading

Download files from github

If this post helped you out, please consider donating to help pay the hosting fees. 100% of the donations go to the web host.

You might also like the ColdFusion and Google Analytics: Getting Out What You Put In post.

Using Alex Curelea’s example of using PHP to hook into Google Analytics through their API, I developed a ColdFusion method. So, same thing as Alex just flavored with CF. The code grabs the profiles and pageviews, then totals up the pageviews for all profiles.

Update: I followed Raymond Camden’s suggestion below and posted another version of this using ClientLogin Authentication.

1. Authenticate user and get token from Google. Basically just a link that sends them off to Google and Google returns them to your page designated in the href with token attached as URL param.

<a href="https://www.google.com/accounts/AuthSubRequest?next=http://www.your-site-here.com/GAwithCF.cfm&scope=https://www.google.com/analytics/feeds/
&secure=0&session=1">Authenticate through Google.</a>

2. Send that token back to Google and get a session token that can be used to retrieve the profile information and data. This is handled in two functions that I originally had in a CFC. I put all the code on one page for this example.

For the session token required for access to the data, the sessionToken function is called with the URL.token passed in.

<cfset authSessionToken = sessionToken(URL.token) />

The sessionToken function makes a get request to https://www.google.com/accounts/AuthSubSessionToken with the token as a header value using the callApi function. The header value must be in the form of Authorization: AuthSub token=”C8b_xxxxxxxxx” with the token equaling the URL.token.
The session token comes back in the form of “Token=CH____88dfdsfsd.” Strip off the “Token=” and you have your session token. The default start and end dates are also set here.

<!---dates for one full year of stats (default)--->
<cfset startdate = DateFormat(DateAdd("d",-365,CreateDate(Year(Now()),Month(Now()),Day(Now()))), "yyyy-mm-dd") />
<cfset enddate = DateFormat(DateAdd("d", -1, Now()),"yyyy-mm-dd") />

<cffunction name="sessionToken" access="public" returntype="string">
	<cfargument name="authToken" type="string" required="yes">

    <cfset var output = callApi("https://www.google.com/accounts/AuthSubSessionToken",arguments.authToken) />
    <cfset var authSubSessionToken = "" />

    <cfset authSubSessionToken = Mid(output, FindNoCase("Token=",output) + (Len("Token=")), Len(output)) />

    <cfreturn authSubSessionToken />
</cffunction>

<cffunction name="callApi" access="public" returntype="string">
    <cfargument name="gaUrl" type="string" required="yes">
    <cfargument name="authToken" type="string" required="yes">

    <cfset var authSubToken = 'AuthSub token="' & arguments.authToken & '"' />
    <cfset var responseOutput = "" />

    <cfhttp url="#arguments.gaUrl#" method="get">
        <cfhttpparam name="Authorization" type="header" value="#authSubToken#">
    </cfhttp>

    <cfset responseOutput = cfhttp.filecontent />

    <cfreturn responseOutput />
</cffunction>

3. Now the callApi function can be used with the authSessionToken to return the account profiles as XML. Unfortunately, it’s an atom feed XML so a little stripping must occur before we can use the handy XMLSearch function in ColdFusion.

<cfset accountXML = callApi("https://www.google.com/analytics/feeds/accounts/default",authSessionToken) />

First we remove the nodes with a dxp: prefix. Then we clear the “xmlns” nodes in the feed element. That’s what bugs up XMLSearch.

<cfset accountXML = accountXML.ReplaceAll("(</?)(\w+:)","$1") />
<cfset accountXML = REReplaceNoCase(accountXML,"<feed[^>]*>","<feed>") />

Anytime you want to take a peek at the XML, you can use cfdump to spit it out for you.

<cfdump var="#XMLParse(accountXML)#">

4. Parse out the XML to put the profiles in an array for easy looping later.

<cfset entryNodes = XmlSearch(accountXML, '//entry/') />

<cfset profileArray = ArrayNew(1) />

<cfloop from="1" to="#ArrayLen(entryNodes)#" index="num">
    <cfset entryStruct = StructNew() />

    <cfset entryStruct.id = entryNodes[num].id.XmlText />
    <cfset entryStruct.title = entryNodes[num].title.XmlText />
    <cfset entryStruct.tableId = entryNodes[num].tableId.XmlText />

    <cfloop from="1" to="#ArrayLen(entryNodes[num].property)#" index="i">
        <cfswitch expression='#entryNodes[num].property[i].XmlAttributes["name"]#'>
            <cfcase value="ga:accountId">
                <cfset entryStruct.accountId = entryNodes[num].property[i].XmlAttributes["value"] />
            </cfcase>
            <cfcase value="ga:accountName">
                <cfset entryStruct.accountName = entryNodes[num].property[i].XmlAttributes["value"] />
            </cfcase>
            <cfcase value="ga:profileId">
                <cfset entryStruct.profileId = entryNodes[num].property[i].XmlAttributes["value"] />
            </cfcase>
            <cfcase value="ga:webPropertyId">
                <cfset entryStruct.webPropertyId = entryNodes[num].property[i].XmlAttributes["value"] />
            </cfcase>
        </cfswitch>
    </cfloop>

    <cfset arrayAppend(profileArray,duplicate(entryStruct)) />

</cfloop>

5. Loop through each profile, grab the metrics you want for each profile from Google, display them on the page, and tally up the total page views count. The XML needs some tidying again but you saw that earlier.

<cfset totalpageviews = 0 />

<cfloop from="1" to="#ArrayLen(profileArray)#" index="num">
    <cfset reqUrl = "https://www.google.com/analytics/feeds/data?ids=" & profileArray[num].tableId & "&metrics=ga:pageviews&start-date=" & startdate & "&end-date=" & enddate />

    <cfset statsXML = callApi(reqUrl,authSessionToken) />
    <!---Tidy up the XML--->
    <cfset statsXML = statsXML.ReplaceAll("(</?)(\w+:)","$1") />
    <cfset statsXML = REReplaceNoCase(statsXML,"<feed[^>]*>","<feed>") />

<cfset metric = XmlSearch(statsXML, '//metric/') />

<cfset pageviews = metric[1].XmlAttributes["value"] />

<cfset totalpageviews = totalpageviews + pageviews />

<p>Profile: #profileArray[num].title# #NumberFormat(pageviews, ",")#</p>

</cfloop>

<p>Total pageviews: #NumberFormat(totalpageviews, ",")#</p>

That’s it. It should at least get you started. Thanks Alex!

Recommended Reading

Download

News of the Google Analytics API

Information on Google AuthSub Proxy Authentication.

Helpful ColdFusion books include the all-in-one ColdFusion MX 7 WACK with tons of good information even if you’ve moved up to CF8. Crazy as it seems, Adobe decided to break up ColdFusion 8 books into three volumes: Volume 1: Getting Started, Volume 2: Application Development, and Volume 3: Advanced Application Development. You may be able to pick up a used copy in good condition. Follow the book’s link above to Amazon and look for used copies underneath the books title.